Excel

Màxim si hi ha diversos criteris

Maximum If Multiple Criteria

Fórmula Excel: màxim si hi ha diversos criterisFórmula genèrica
{= MAX ( IF (rng1=criteria1, IF (rng2=criteria2,values)))}
Resum

Per obtenir el valor màxim d'un conjunt de dades basat en més d'un criteri, podeu utilitzar una fórmula de matriu basada en les funcions MAX i IF. A l'exemple que es mostra, la fórmula de I6 és:



 
{= MAX ( IF (color=G6, IF (item=H6,price)))}

Amb un color de 'vermell' i l'element de 'barret' el resultat és d'11,00 $

Nota: Aquesta és una fórmula de matriu i s'ha d'introduir mitjançant Ctrl + Maj + introduït





Explicació

Aquest exemple utilitza el següent intervals amb nom : 'color' = B6: B14, 'article' = C6: C14 i 'preu' = E6: E14. L’objectiu és trobar el preu màxim per a un color i un article determinats.

Aquesta fórmula utilitza dues funcions IF imbricades, incloses dins de MAX per retornar el preu màxim amb dos criteris. Començant per una prova lògica de la primera sentència IF, color = G6, els valors de l'interval anomenat 'color' (B6: B14) es comproven amb el valor de la cel·la G6, 'vermell'. El resultat és una matriu com aquesta:



 
{TRUETRUETRUEFALSEFALSEFALSEFALSEFALSEFALSE}

A la prova lògica de la segona sentència IF, ítem = H6, els valors de l’element d’interval anomenat (C6: C14) es comproven amb el valor de la cel·la H6, “barret”. El resultat és una matriu com aquesta:

 
{TRUETRUETRUETRUETRUETRUEFALSEFALSEFALSE}

El 'valor si és cert' per a la 2a sentència IF és l'interval anomenat 'preus' (E6: E14), que és una matriu com aquesta:

 
{118912910987}

Es torna un preu per cada article d’aquest interval només quan el resultat de les dues primeres matrius anteriors és CERT per a ítems en posicions corresponents. A l'exemple que es mostra, la matriu final dins de MAX té aquest aspecte:

 
{1189FALSEFALSEFALSEFALSEFALSEFALSE}

Tingueu en compte que els únics preus que 'sobreviuen' són els que es troben en una posició en què el color és 'vermell' i l'article és 'barret'.

La funció MAX retorna el preu més alt, ignorant automàticament els valors FALS.

Sintaxi alternativa mitjançant lògica booleana

També podeu utilitzar la següent fórmula de matriu, que només utilitza una funció IF juntament amb lògica booleana :

quina funció de text posa en majúscula la primera lletra d'una cadena de text?
 
{= MAX ( IF ((color=G6)*(item=H6),price))}

L’avantatge d’aquesta sintaxi és que és més fàcil afegir criteris addicionals sense afegir funcions IF imbricades addicionals. Si necessiteu una lògica OR, utilitzeu la suma en lloc de multiplicar les condicions.

Amb MAXIFS

El Funció MAXIFS , introduït a Excel 2016, està dissenyat per calcular els màxims en funció d’un o més criteris sense necessitat d’una fórmula de matriu. Amb MAXIFS, la fórmula de I6 és:

 
= MAXIFS (price,color,G6,item,H6)

Nota: MAXIFS es farà automàticament ignorar cel·les buides que compleixen els criteris. En altres paraules, MAXIFS no tractarà les cel·les buides que compleixen els criteris com a zero. D’altra banda, MAXIFS voluntat torna zero (0) si cap cel·la coincideix amb els criteris.

Autor Dave Bruns


^